1/****************************************************************************
2**
3** Copyright (C) 2017 The Qt Company Ltd.
4** Contact: https://www.qt.io/licensing/
5**
6** This file is part of the QtTest module of the Qt Toolkit.
7**
8** $QT_BEGIN_LICENSE:LGPL$
9** Commercial License Usage
10** Licensees holding valid commercial Qt licenses may use this file in
11** accordance with the commercial license agreement provided with the
12** Software or, alternatively, in accordance with the terms contained in
13** a written agreement between you and The Qt Company. For licensing terms
14** and conditions see https://www.qt.io/terms-conditions. For further
15** information use the contact form at https://www.qt.io/contact-us.
16**
17** GNU Lesser General Public License Usage
18** Alternatively, this file may be used under the terms of the GNU Lesser
19** General Public License version 3 as published by the Free Software
20** Foundation and appearing in the file LICENSE.LGPL3 included in the
21** packaging of this file. Please review the following information to
22** ensure the GNU Lesser General Public License version 3 requirements
23** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
24**
25** GNU General Public License Usage
26** Alternatively, this file may be used under the terms of the GNU
27** General Public License version 2.0 or (at your option) the GNU General
28** Public license version 3 or any later version approved by the KDE Free
29** Qt Foundation. The licenses are as published by the Free Software
30** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
31** included in the packaging of this file. Please review the following
32** information to ensure the GNU General Public License requirements will
33** be met: https://www.gnu.org/licenses/gpl-2.0.html and
34** https://www.gnu.org/licenses/gpl-3.0.html.
35**
36** $QT_END_LICENSE$
37**
38****************************************************************************/
39
40#include "qtestutil_macos_p.h"
41
42#include "QtCore/private/qcore_mac_p.h"
43
44#import <AppKit/AppKit.h>
45
46QT_BEGIN_NAMESPACE
47
48namespace QTestPrivate {
49
50 /*! \internal
51
52 Disables restoration of previously saved window state. This causes tests
53 to start with a clean slate and prevents the "previous restore failed"
54 dialog from showing if there was a test crash.
55 */
56 void disableWindowRestore() {
57 [[NSUserDefaults standardUserDefaults] setBool:YES forKey:@"ApplePersistenceIgnoreState"];
58 }
59
60 bool macCrashReporterWillShowDialog()
61 {
62 auto dialogType = QCFType<CFStringRef>(CFPreferencesCopyAppValue(
63 CFSTR("DialogType"), CFSTR("com.apple.CrashReporter")));
64
65 auto stringCompare = [](CFStringRef str1, CFStringRef str2) -> bool {
66 return CFStringCompare(str1, str2, kCFCompareCaseInsensitive) == kCFCompareEqualTo;
67 };
68
69 if (!dialogType || stringCompare(dialogType, CFSTR("basic"))) {
70 // The default (basic) dialog type only shows up if the
71 // application is 'user visible', as indicated by the
72 // activation policy.
73 auto *runningApp = NSRunningApplication.currentApplication;
74 return runningApp && runningApp.activationPolicy == NSApplicationActivationPolicyRegular;
75 } else if (stringCompare(dialogType, CFSTR("developer"))
76 || stringCompare(dialogType, CFSTR("crashreport"))) {
77 // While in developer mode the dialog will show for all
78 // crashed applications, including backgrounded ones.
79 return true;
80 } else {
81 // Finally, 'server' or 'none' will result in no dialog
82 return false;
83 }
84 }
85
86 /*! \internal
87 \class AppNapDisabler
88 \brief Disables App Nap by registereing a bacground activity.
89
90 App Nap remains disabled as long as the AppNapDisabler instance
91 exists.
92 */
93
94 /*! \internal
95 Creates an AppNapDisabler instance and starts a NSActivityBackground activity.
96 */
97 AppNapDisabler::AppNapDisabler()
98 {
99 m_activity = [[NSProcessInfo processInfo] beginActivityWithOptions:NSActivityBackground
100 reason:@"Qt Auto Test"];
101 [m_activity retain];
102 }
103
104 /*! \internal
105 Destroys the AppNapDisabler instance and ends the NSActivityBackground activity.
106 */
107 AppNapDisabler::~AppNapDisabler()
108 {
109 [[NSProcessInfo processInfo] endActivity:m_activity];
110 [m_activity release];
111 }
112}
113
114QT_END_NAMESPACE
115