Warning: That file was not part of the compilation database. It may have many parsing errors.

1/* Copyright (C) 1996-2019 Free Software Foundation, Inc.
2 This file is part of the GNU C Library.
3 Contributed by Richard Henderson <rth@tamu.edu>, 1996.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library. If not, see
17 <http://www.gnu.org/licenses/>. */
18
19/* Append a null-terminated string from SRC to DST. */
20
21#include <sysdep.h>
22
23 .text
24
25ENTRY(strcat)
26 ldgp gp, 0(pv)
27#ifdef PROF
28 .set noat
29 lda AT, _mcount
30 jsr AT, (AT), _mcount
31 .set at
32#endif
33 .prologue 1
34
35 mov a0, v0 # set up return value
36
37 /* Find the end of the string. */
38
39 ldq_u t0, 0(a0) # load first quadword (a0 may be misaligned)
40 lda t1, -1(zero)
41 insqh t1, a0, t1
42 andnot a0, 7, a0
43 or t1, t0, t0
44 cmpbge zero, t0, t1 # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
45 bne t1, $found
46
47$loop: ldq t0, 8(a0)
48 addq a0, 8, a0 # addr += 8
49 cmpbge zero, t0, t1
50 beq t1, $loop
51
52$found: negq t1, t2 # clear all but least set bit
53 and t1, t2, t1
54
55 and t1, 0xf0, t2 # binary search for that set bit
56 and t1, 0xcc, t3
57 and t1, 0xaa, t4
58 cmovne t2, 4, t2
59 cmovne t3, 2, t3
60 cmovne t4, 1, t4
61 addq t2, t3, t2
62 addq a0, t4, a0
63 addq a0, t2, a0
64
65 /* Now do the append. */
66
67 mov ra, t9
68 jmp $31, __stxcpy
69
70 END(strcat)
71libc_hidden_builtin_def (strcat)
72

Warning: That file was not part of the compilation database. It may have many parsing errors.