1 | ;! HP-PA __udiv_qrnnd division support, used from longlong.h. |
2 | ;! This version runs fast on PA 7000 and later. |
3 | |
4 | ;! Copyright (C) 1993-2022 Free Software Foundation, Inc. |
5 | |
6 | ;! This file is part of the GNU MP Library. |
7 | |
8 | ;! The GNU MP Library is free software; you can redistribute it and/or modify |
9 | ;! it under the terms of the GNU Lesser General Public License as published by |
10 | ;! the Free Software Foundation; either version 2.1 of the License, or (at your |
11 | ;! option) any later version. |
12 | |
13 | ;! The GNU MP Library is distributed in the hope that it will be useful, but |
14 | ;! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
15 | ;! or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
16 | ;! License for more details. |
17 | |
18 | ;! You should have received a copy of the GNU Lesser General Public License |
19 | ;! along with the GNU MP Library. If not, see |
20 | ;! <https://www.gnu.org/licenses/>. |
21 | |
22 | |
23 | ;! INPUT PARAMETERS |
24 | ;! rem_ptr gr26 |
25 | ;! n1 gr25 |
26 | ;! n0 gr24 |
27 | ;! d gr23 |
28 | |
29 | .text |
30 | L$0000: |
31 | .word 0x43f00000 |
32 | .word 0x0 |
33 | .export __udiv_qrnnd |
34 | __udiv_qrnnd: |
35 | .proc |
36 | .callinfo frame=64,no_calls |
37 | .entry |
38 | ldo 64(%r30),%r30 |
39 | |
40 | stws %r25,-16(%r30) ;! n_hi |
41 | stws %r24,-12(%r30) ;! n_lo |
42 | b,l L$0,%r1 |
43 | ldo L$0000-L$0(%r1),%r1 |
44 | L$0: |
45 | fldds -16(%r30),%fr5 |
46 | stws %r23,-12(%r30) |
47 | comib,<= 0,%r25,L$1 |
48 | fcnvxf,dbl,dbl %fr5,%fr5 |
49 | fldds 0(%r1),%fr4 |
50 | fadd,dbl %fr4,%fr5,%fr5 |
51 | L$1: |
52 | fcpy,sgl %fr0,%fr6L |
53 | fldws -12(%r30),%fr6R |
54 | fcnvxf,dbl,dbl %fr6,%fr4 |
55 | |
56 | fdiv,dbl %fr5,%fr4,%fr5 |
57 | |
58 | fcnvfx,dbl,dbl %fr5,%fr4 |
59 | fstws %fr4R,-16(%r30) |
60 | xmpyu %fr4R,%fr6R,%fr6 |
61 | ldws -16(%r30),%r28 |
62 | fstds %fr6,-16(%r30) |
63 | ldws -12(%r30),%r21 |
64 | ldws -16(%r30),%r20 |
65 | sub %r24,%r21,%r22 |
66 | subb %r25,%r20,%r1 |
67 | comib,= 0,%r1,L$2 |
68 | ldo -64(%r30),%r30 |
69 | |
70 | add %r22,%r23,%r22 |
71 | ldo -1(%r28),%r28 |
72 | L$2: |
73 | bv 0(%r2) |
74 | stws %r22,0(%r26) |
75 | |
76 | .exit |
77 | .procend |
78 | |