| 1 | /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'. i386 version. |
|---|
| 2 | Copyright (C) 1994-2022 Free Software Foundation, Inc. |
|---|
| 3 | This file is part of the GNU C Library. |
|---|
| 4 | |
|---|
| 5 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 6 | modify it under the terms of the GNU Lesser General Public |
|---|
| 7 | License as published by the Free Software Foundation; either |
|---|
| 8 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 9 | |
|---|
| 10 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 11 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 12 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 13 | Lesser General Public License for more details. |
|---|
| 14 | |
|---|
| 15 | You should have received a copy of the GNU Lesser General Public |
|---|
| 16 | License along with the GNU C Library; if not, see |
|---|
| 17 | <https://www.gnu.org/licenses/>. */ |
|---|
| 18 | |
|---|
| 19 | /* This just does a tail-call to `__sigsetjmp (ARG, 1)'. |
|---|
| 20 | We cannot do it in C because it must be a tail-call, so frame-unwinding |
|---|
| 21 | in setjmp doesn't clobber the state restored by longjmp. */ |
|---|
| 22 | |
|---|
| 23 | #include <sysdep.h> |
|---|
| 24 | #include <jmpbuf-offsets.h> |
|---|
| 25 | #include <jmp_buf-ssp.h> |
|---|
| 26 | #include <stap-probe.h> |
|---|
| 27 | |
|---|
| 28 | #define PARMS 4 /* no space for saved regs */ |
|---|
| 29 | #define JMPBUF PARMS |
|---|
| 30 | #define SIGMSK JMPBUF+4 |
|---|
| 31 | |
|---|
| 32 | /* Don't save shadow stack register if shadow stack isn't enabled. */ |
|---|
| 33 | #if !SHSTK_ENABLED |
|---|
| 34 | # undef SHADOW_STACK_POINTER_OFFSET |
|---|
| 35 | #endif |
|---|
| 36 | |
|---|
| 37 | ENTRY (setjmp) |
|---|
| 38 | /* Note that we have to use a non-exported symbol in the next |
|---|
| 39 | jump since otherwise gas will emit it as a jump through the |
|---|
| 40 | PLT which is what we cannot use here. */ |
|---|
| 41 | |
|---|
| 42 | movl JMPBUF(%esp), %eax |
|---|
| 43 | |
|---|
| 44 | /* Save registers. */ |
|---|
| 45 | movl %ebx, (JB_BX*4)(%eax) |
|---|
| 46 | movl %esi, (JB_SI*4)(%eax) |
|---|
| 47 | movl %edi, (JB_DI*4)(%eax) |
|---|
| 48 | leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return. */ |
|---|
| 49 | #ifdef PTR_MANGLE |
|---|
| 50 | PTR_MANGLE (%ecx) |
|---|
| 51 | #endif |
|---|
| 52 | movl %ecx, (JB_SP*4)(%eax) |
|---|
| 53 | movl 0(%esp), %ecx /* Save PC we are returning to now. */ |
|---|
| 54 | LIBC_PROBE (setjmp, 3, 4@%eax, -4@$1, 4@%ecx) |
|---|
| 55 | #ifdef PTR_MANGLE |
|---|
| 56 | PTR_MANGLE (%ecx) |
|---|
| 57 | #endif |
|---|
| 58 | movl %ecx, (JB_PC*4)(%eax) |
|---|
| 59 | movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer. */ |
|---|
| 60 | #ifdef SHADOW_STACK_POINTER_OFFSET |
|---|
| 61 | # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET |
|---|
| 62 | /* Check if Shadow Stack is enabled. */ |
|---|
| 63 | testl $X86_FEATURE_1_SHSTK, %gs:FEATURE_1_OFFSET |
|---|
| 64 | jz L(skip_ssp) |
|---|
| 65 | # else |
|---|
| 66 | xorl %ecx, %ecx |
|---|
| 67 | # endif |
|---|
| 68 | /* Get the current Shadow-Stack-Pointer and save it. */ |
|---|
| 69 | rdsspd %ecx |
|---|
| 70 | movl %ecx, SHADOW_STACK_POINTER_OFFSET(%eax) |
|---|
| 71 | # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET |
|---|
| 72 | L(skip_ssp): |
|---|
| 73 | # endif |
|---|
| 74 | #endif |
|---|
| 75 | |
|---|
| 76 | /* Call __sigjmp_save. */ |
|---|
| 77 | pushl $1 |
|---|
| 78 | cfi_adjust_cfa_offset (4) |
|---|
| 79 | pushl 8(%esp) |
|---|
| 80 | cfi_adjust_cfa_offset (4) |
|---|
| 81 | call __sigjmp_save |
|---|
| 82 | popl %ecx |
|---|
| 83 | cfi_adjust_cfa_offset (-4) |
|---|
| 84 | popl %edx |
|---|
| 85 | cfi_adjust_cfa_offset (-4) |
|---|
| 86 | ret |
|---|
| 87 | END (setjmp) |
|---|
| 88 | |
|---|
