1 | /* Special .init and .fini section support for IA64. |
2 | Copyright (C) 2000-2022 Free Software Foundation, Inc. |
3 | This file is part of the GNU C Library. |
4 | |
5 | The GNU C Library is free software; you can redistribute it and/or |
6 | modify it under the terms of the GNU Lesser General Public |
7 | License as published by the Free Software Foundation; either |
8 | version 2.1 of the License, or (at your option) any later version. |
9 | |
10 | In addition to the permissions in the GNU Lesser General Public |
11 | License, the Free Software Foundation gives you unlimited |
12 | permission to link the compiled version of this file with other |
13 | programs, and to distribute those programs without any restriction |
14 | coming from the use of this file. (The GNU Lesser General Public |
15 | License restrictions do apply in other respects; for example, they |
16 | cover modification of the file, and distribution when not linked |
17 | into another program.) |
18 | |
19 | Note that people who make modified versions of this file are not |
20 | obligated to grant this special exception for their modified |
21 | versions; it is their choice whether to do so. The GNU Lesser |
22 | General Public License gives permission to release a modified |
23 | version without this exception; this exception also makes it |
24 | possible to release a modified version which carries forward this |
25 | exception. |
26 | |
27 | The GNU C Library is distributed in the hope that it will be useful, |
28 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
29 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
30 | Lesser General Public License for more details. |
31 | |
32 | You should have received a copy of the GNU Lesser General Public |
33 | License along with the GNU C Library. If not, see |
34 | <https://www.gnu.org/licenses/>. */ |
35 | |
36 | /* crti.S puts a function prologue at the beginning of the .init and |
37 | .fini sections and defines global symbols for those addresses, so |
38 | they can be called as functions. The symbols _init and _fini are |
39 | magic and cause the linker to emit DT_INIT and DT_FINI. */ |
40 | |
41 | #include <libc-symbols.h> |
42 | #include <sysdep.h> |
43 | #undef ret |
44 | |
45 | #ifndef PREINIT_FUNCTION |
46 | # define PREINIT_FUNCTION __gmon_start__ |
47 | #endif |
48 | |
49 | #ifndef PREINIT_FUNCTION_WEAK |
50 | # define PREINIT_FUNCTION_WEAK 1 |
51 | #endif |
52 | |
53 | #if PREINIT_FUNCTION_WEAK |
54 | weak_extern (PREINIT_FUNCTION) |
55 | #else |
56 | .hidden PREINIT_FUNCTION |
57 | #endif |
58 | |
59 | /* If we have working .init_array support, we want to keep the .init |
60 | section empty (apart from the mandatory prologue/epilogue. This |
61 | ensures that the default unwind conventions (return-pointer in b0, |
62 | frame state in ar.pfs, etc.) will do the Right Thing. To ensure |
63 | an empty .init section, we register gmon_initializer() via the |
64 | .init_array. |
65 | |
66 | --davidm 02/10/29 */ |
67 | |
68 | #if PREINIT_FUNCTION_WEAK |
69 | /* This blob of assembly code is one simple C function: |
70 | |
71 | static void |
72 | __attribute__ ((used)) |
73 | gmon_initializer (void) |
74 | { |
75 | extern void weak_function __gmon_start__ (void); |
76 | |
77 | if (__gmon_start__) |
78 | (*__gmon_start__)(); |
79 | } |
80 | */ |
81 | .text |
82 | .align 64 |
83 | .proc gmon_initializer# |
84 | gmon_initializer: |
85 | .prologue 12, 32 |
86 | .mmi |
87 | .save ar.pfs, r33 |
88 | alloc r33 = ar.pfs, 0, 3, 0, 0 |
89 | addl r14 = @ltoff(@fptr(PREINIT_FUNCTION#)), gp |
90 | .save rp, r32 |
91 | mov r32 = b0 |
92 | .mmi |
93 | mov r34 = r1 |
94 | .body |
95 | ;; |
96 | ld8 r14 = [r14] |
97 | nop 0 |
98 | ;; |
99 | .mib |
100 | cmp.eq p6, p7 = 0, r14 |
101 | nop 0 |
102 | (p6) br.cond.spnt .L1 |
103 | ;; |
104 | .mib |
105 | nop 0 |
106 | nop 0 |
107 | br.call.sptk.many b0 = PREINIT_FUNCTION# |
108 | ;; |
109 | .mmi |
110 | mov r1 = r34 |
111 | nop 0 |
112 | nop 0 |
113 | .L1: |
114 | .mii |
115 | nop 0 |
116 | mov ar.pfs = r33 |
117 | nop 0 |
118 | ;; |
119 | .mib |
120 | nop 0 |
121 | mov b0 = r32 |
122 | br.ret.sptk.many b0 |
123 | .endp gmon_initializer# |
124 | # undef PREINIT_FUNCTION |
125 | # define PREINIT_FUNCTION gmon_initializer |
126 | #endif |
127 | .section .init_array, "aw" |
128 | data8 @fptr(PREINIT_FUNCTION) |
129 | |
130 | .section .init,"ax" ,@progbits |
131 | .global _init# |
132 | .hidden _init# |
133 | .proc _init# |
134 | _init: |
135 | .prologue |
136 | .save ar.pfs, r34 |
137 | alloc r34 = ar.pfs, 0, 3, 0, 0 |
138 | .vframe r32 |
139 | mov r32 = r12 |
140 | .save rp, r33 |
141 | mov r33 = b0 |
142 | .body |
143 | adds r12 = -16, r12 |
144 | ;; /* see gmon_initializer() above */ |
145 | .endp _init# |
146 | |
147 | .section .fini,"ax" ,@progbits |
148 | .global _fini# |
149 | .hidden _fini# |
150 | .proc _fini# |
151 | _fini: |
152 | .prologue |
153 | .save ar.pfs, r34 |
154 | alloc r34 = ar.pfs, 0, 3, 0, 0 |
155 | .vframe r32 |
156 | mov r32 = r12 |
157 | .save rp, r33 |
158 | mov r33 = b0 |
159 | .body |
160 | adds r12 = -16, r12 |
161 | ;; |
162 | .endp _fini# |
163 | |