1/* Vector optimized 32/64 bit S/390 version of wcpcpy.
2 Copyright (C) 2015-2022 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <ifunc-wcpcpy.h>
20#if HAVE_WCPCPY_Z13
21
22# include "sysdep.h"
23# include "asm-syntax.h"
24
25 .text
26
27/* wchar_t * wcpcpy (const wchar_t *dest, const wchar_t *src)
28 Copy string src to dest returning a pointer to its end.
29
30 Register usage:
31 -r0=border-len for switching to vector-instructions
32 -r1=tmp
33 -r2=dest and return value
34 -r3=src
35 -r4=tmp
36 -r5=current_len
37 -v16=part of src
38 -v17=index of zero
39 -v18=part of src
40*/
41ENTRY(WCPCPY_Z13)
42 .machine "z13"
43 .machinemode "zarch_nohighgprs"
44
45 vlbb %v16,0(%r3),6 /* Load s until next 4k-byte boundary. */
46 lcbb %r1,0(%r3),6 /* Get bytes to 4k-byte boundary or 16. */
47
48 tmll %r3,3 /* Test if s is 4-byte aligned? */
49 jne .Lfallback /* And use common-code variant if not. */
50
51 vfenezf %v17,%v16,%v16 /* Find element not equal with zero search. */
52 vlgvb %r5,%v17,7 /* Load zero index or 16 if not found. */
53 clrjl %r5,%r1,.Lfound_align /* If found zero within loaded bytes,
54 copy bytes before and return. */
55
56 /* Align s to 16 byte. */
57 risbgn %r4,%r3,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
58 lghi %r5,15 /* current_len = 15. */
59 slr %r5,%r4 /* Compute highest index to 16byte boundary. */
60
61 vstl %v16,%r5,0(%r2) /* Copy loaded characters - no zero. */
62 ahi %r5,1 /* Start loop at next character. */
63
64 /* Find zero in 16byte aligned loop. */
65.Lloop:
66 vl %v16,0(%r5,%r3) /* Load s. */
67 vfenezfs %v17,%v16,%v16 /* Find element not equal with zero search. */
68 je .Lfound_v16_0 /* Jump away if zero was found. */
69 vl %v18,16(%r5,%r3) /* Load next part of s. */
70 vst %v16,0(%r5,%r2) /* Store previous part without zero to dst. */
71 vfenezfs %v17,%v18,%v18
72 je .Lfound_v18_16
73 vl %v16,32(%r5,%r3)
74 vst %v18,16(%r5,%r2)
75 vfenezfs %v17,%v16,%v16
76 je .Lfound_v16_32
77 vl %v18,48(%r5,%r3)
78 vst %v16,32(%r5,%r2)
79 vfenezfs %v17,%v18,%v18
80 je .Lfound_v18_48
81 vst %v18,48(%r5,%r2)
82
83 aghi %r5,64
84 j .Lloop /* No zero found -> loop. */
85
86.Lfound_v16_32:
87 aghi %r5,32
88.Lfound_v16_0:
89 la %r3,0(%r5,%r2)
90 vlgvb %r1,%v17,7 /* Load byte index of zero. */
91 aghi %r1,3 /* Also copy remaining bytes of zero. */
92 vstl %v16,%r1,0(%r3) /* Copy characters including zero. */
93 lay %r2,-3(%r1,%r3) /* Return pointer to zero. */
94 br %r14
95
96.Lfound_v18_48:
97 aghi %r5,32
98.Lfound_v18_16:
99 la %r3,16(%r5,%r2)
100 vlgvb %r1,%v17,7 /* Load byte index of zero. */
101 aghi %r1,3 /* Also copy remaining bytes of zero. */
102 vstl %v18,%r1,0(%r3) /* Copy characters including zero. */
103 lay %r2,-3(%r1,%r3) /* Return pointer to zero. */
104 br %r14
105
106.Lfound_align:
107 aghi %r5,3 /* Also copy remaining bytes of zero. */
108 vstl %v16,%r5,0(%r2) /* Copy characters including zero. */
109 lay %r2,-3(%r5,%r2) /* Return pointer to zero. */
110 br %r14
111
112.Lfallback:
113 jg WCPCPY_C
114END(WCPCPY_Z13)
115
116# if ! HAVE_WCPCPY_IFUNC
117strong_alias (WCPCPY_Z13, __wcpcpy)
118weak_alias (__wcpcpy, wcpcpy)
119# endif
120#endif
121

source code of glibc/sysdeps/s390/wcpcpy-vx.S