1/* Vector optimized 32/64 bit S/390 version of wcschr.
2 Copyright (C) 2015-2022 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <ifunc-wcschr.h>
20#if HAVE_WCSCHR_Z13
21
22# include "sysdep.h"
23# include "asm-syntax.h"
24
25 .text
26
27/* wchar_t *wcschr (const wchar_t *s, wchar_t c)
28 Locate character in string.
29
30 Register usage:
31 -r1=tmp
32 -r2=s
33 -r3=c
34 -r4=tmp
35 -r5=current_len
36 -v16=part of s
37 -v17=index of unequal
38 -v18=replicated c
39*/
40ENTRY(WCSCHR_Z13)
41 .machine "z13"
42 .machinemode "zarch_nohighgprs"
43
44 vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */
45 lcbb %r1,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */
46
47 tmll %r2,3 /* Test if s is 4-byte aligned? */
48 jne .Lfallback /* And use common-code variant if not. */
49
50 lghi %r5,0 /* current_len = 0. */
51
52 vlvgf %v18,%r3,0 /* Generate vector which elements are all c. */
53 vrepf %v18,%v18,0
54
55 vfeezfs %v16,%v16,%v18 /* Find element equal with zero search. */
56 vlgvb %r4,%v16,7 /* Load byte index of character or zero. */
57 clrjl %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes. */
58
59 /* Align s to 16 byte. */
60 risbgn %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
61 lghi %r5,16 /* current_len = 16. */
62 slr %r5,%r4 /* Compute bytes to 16bytes boundary. */
63
64 /* Find c/zero in 16byte aligned loop */
65.Lloop:
66 vl %v16,0(%r5,%r2) /* Load s. */
67 vfeezfs %v16,%v16,%v18 /* Find element equal with zero search. */
68 jno .Lfound /* Found c/zero (cc=0|1|2). */
69 vl %v16,16(%r5,%r2)
70 vfeezfs %v16,%v16,%v18
71 jno .Lfound16
72 vl %v16,32(%r5,%r2)
73 vfeezfs %v16,%v16,%v18
74 jno .Lfound32
75 vl %v16,48(%r5,%r2)
76 vfeezfs %v16,%v16,%v18
77 jno .Lfound48
78
79 aghi %r5,64
80 j .Lloop /* No character and no zero -> loop. */
81
82.Lfound48:
83 la %r5,16(%r5) /* Use la since aghi would clobber cc. */
84.Lfound32:
85 la %r5,16(%r5)
86.Lfound16:
87 la %r5,16(%r5)
88.Lfound:
89 je .Lzero /* Found zero, but no c before that zero. */
90
91.Lcharacter:
92 vlgvb %r4,%v16,7 /* Load byte index of character. */
93 algr %r5,%r4
94 la %r2,0(%r5,%r2) /* Return pointer to character. */
95 br %r14
96
97.Lzero:
98 clije %r3,0,.Lcharacter /* Found zero and c is zero. */
99 lghi %r2,0 /* Return null if character not found. */
100 br %r14
101.Lfallback:
102 jg WCSCHR_C
103END(WCSCHR_Z13)
104
105# if ! HAVE_WCSCHR_IFUNC
106strong_alias (WCSCHR_Z13, __wcschr)
107weak_alias (__wcschr, wcschr)
108# endif
109
110# if defined HAVE_S390_MIN_Z13_ZARCH_ASM_SUPPORT \
111 && defined SHARED && IS_IN (libc)
112strong_alias (WCSCHR_Z13, __GI___wcschr)
113weak_alias (WCSCHR_Z13, __GI_wcschr)
114# endif
115#endif
116

source code of glibc/sysdeps/s390/wcschr-vx.S