1 | /* Copyright (C) 1999-2022 Free Software Foundation, Inc. |
2 | |
3 | The GNU C Library is free software; you can redistribute it and/or |
4 | modify it under the terms of the GNU Lesser General Public |
5 | License as published by the Free Software Foundation; either |
6 | version 2.1 of the License, or (at your option) any later version. |
7 | |
8 | The GNU C Library is distributed in the hope that it will be useful, |
9 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
10 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
11 | Lesser General Public License for more details. |
12 | |
13 | You should have received a copy of the GNU Lesser General Public |
14 | License along with the GNU C Library; if not, see |
15 | <https://www.gnu.org/licenses/>. */ |
16 | |
17 | #include <sysdep.h> |
18 | #include <features.h> |
19 | |
20 | LEAF(__ia64_flush_rbs) |
21 | flushrs |
22 | mov r9 = ar.rsc // 12 cyc latency |
23 | ;; |
24 | mov r8 = ar.bsp // 12 cyc latency |
25 | ;; |
26 | and r16 = ~0x3, r9 // clear ar.rsc.mode |
27 | ;; |
28 | mov ar.rsc = r16 // put RSE into enforced-lazy mode |
29 | ;; |
30 | mov r10 = ar.rnat // 5 cyc latency |
31 | ret |
32 | END(__ia64_flush_rbs) |
33 | |
34 | |
35 | # define pPos p6 /* is rotate count positive? */ |
36 | # define pNeg p7 /* is rotate count negative? */ |
37 | |
38 | /* __ia64_longjmp(__jmp_buf buf, int val, long rnat, long rsc) */ |
39 | |
40 | |
41 | LEAF(__ia64_longjmp) |
42 | alloc r8=ar.pfs,4,0,0,0 |
43 | add r2=0x98,in0 // r2 <- &jmpbuf.orig_jmp_buf_addr |
44 | add r3=0x88,in0 // r3 <- &jmpbuf.ar_bsp |
45 | ;; |
46 | ld8 r8=[r2] // r8 <- orig_jmp_buf_addr |
47 | ld8 r23=[r3],8 // r23 <- jmpbuf.ar_bsp |
48 | mov r2=in0 |
49 | ;; |
50 | // |
51 | // Note: we need to redo the "flushrs" here even though it's |
52 | // already been done by __ia64_flush_rbs. It is needed to |
53 | // ensure that ar.bspstore == ar.bsp. |
54 | // |
55 | flushrs // flush dirty regs to backing store |
56 | ld8 r25=[r3] // r25 <- jmpbuf.ar_unat |
57 | sub r8=r8,in0 // r8 <- &orig_jmpbuf - &jmpbuf |
58 | ;; |
59 | add r3=8,in0 // r3 <- &jmpbuf.r1 |
60 | extr.u r8=r8,3,6 // r8 <- (&orig_jmpbuf - &jmpbuf)/8 & 0x3f |
61 | ;; |
62 | cmp.lt pNeg,pPos=r8,r0 |
63 | ;; |
64 | (pPos) mov r16=r8 |
65 | (pNeg) add r16=64,r8 |
66 | (pPos) sub r17=64,r8 |
67 | (pNeg) sub r17=r0,r8 |
68 | ;; |
69 | shr.u r8=r25,r16 |
70 | shl r9=r25,r17 |
71 | ;; |
72 | or r25=r8,r9 |
73 | ;; |
74 | mov ar.unat=r25 // setup ar.unat (NaT bits for r1, r4-r7, and r12) |
75 | ;; |
76 | ld8.fill.nta sp=[r2],16 // r12 (sp) |
77 | ld8.fill.nta gp=[r3],32 // r1 (gp) |
78 | dep r11=-1,r23,3,6 // r11 <- ia64_rse_rnat_addr(jmpbuf.ar_bsp) |
79 | ;; |
80 | ld8.nta r16=[r2],16 // caller's unat |
81 | // ld8.nta r17=[r3],16 // fpsr |
82 | ;; |
83 | ld8.fill.nta r4=[r2],16 // r4 |
84 | ld8.fill.nta r5=[r3],16 // r5 (gp) |
85 | ;; |
86 | ld8.fill.nta r6=[r2],16 // r6 |
87 | ld8.fill.nta r7=[r3],16 // r7 |
88 | ;; |
89 | mov ar.unat=r16 // restore caller's unat |
90 | // mov ar.fpsr=r17 // restore fpsr |
91 | ;; |
92 | ld8.nta r16=[r2],16 // b0 |
93 | ld8.nta r17=[r3],16 // b1 |
94 | ;; |
95 | mov ar.bspstore=r23 // restore ar.bspstore |
96 | ld8.nta r18=[r2],16 // b2 |
97 | ;; |
98 | mov ar.rnat=in2 // restore ar.rnat |
99 | ld8.nta r19=[r3],16 // b3 |
100 | ;; |
101 | ld8.nta r20=[r2],16 // b4 |
102 | ld8.nta r21=[r3],16 // b5 |
103 | #ifdef PTR_DEMANGLE |
104 | PTR_DEMANGLE (r16, r24) |
105 | #endif |
106 | ;; |
107 | ld8.nta r11=[r2],16 // ar.pfs |
108 | ld8.nta r22=[r3],56 // ar.lc |
109 | ;; |
110 | ld8.nta r24=[r2],32 // pr |
111 | mov ar.rsc=in3 // restore ar.rsc |
112 | mov b0=r16 |
113 | ;; |
114 | ldf.fill.nta f2=[r2],32 |
115 | ldf.fill.nta f3=[r3],32 |
116 | mov b1=r17 |
117 | ;; |
118 | ldf.fill.nta f4=[r2],32 |
119 | ldf.fill.nta f5=[r3],32 |
120 | mov b2=r18 |
121 | ;; |
122 | ldf.fill.nta f16=[r2],32 |
123 | ldf.fill.nta f17=[r3],32 |
124 | mov b3=r19 |
125 | ;; |
126 | ldf.fill.nta f18=[r2],32 |
127 | ldf.fill.nta f19=[r3],32 |
128 | mov b4=r20 |
129 | ;; |
130 | ldf.fill.nta f20=[r2],32 |
131 | ldf.fill.nta f21=[r3],32 |
132 | mov b5=r21 |
133 | ;; |
134 | ldf.fill.nta f22=[r2],32 |
135 | ldf.fill.nta f23=[r3],32 |
136 | mov ar.lc=r22 |
137 | ;; |
138 | ldf.fill.nta f24=[r2],32 |
139 | ldf.fill.nta f25=[r3],32 |
140 | cmp.eq p8,p9=0,in1 |
141 | ;; |
142 | ldf.fill.nta f26=[r2],32 |
143 | ldf.fill.nta f27=[r3],32 |
144 | mov ar.pfs=r11 |
145 | ;; |
146 | ldf.fill.nta f28=[r2],32 |
147 | ldf.fill.nta f29=[r3],32 |
148 | (p8) mov r8=1 |
149 | ;; |
150 | ldf.fill.nta f30=[r2] |
151 | ldf.fill.nta f31=[r3] |
152 | (p9) mov r8=in1 |
153 | |
154 | invala // virt. -> phys. regnum mapping may change |
155 | mov pr=r24,-1 |
156 | ret |
157 | END(__ia64_longjmp) |
158 | |