1 | /* Copyright (C) 1997-2022 Free Software Foundation, Inc. |
2 | This file is part of the GNU C Library. |
3 | |
4 | The GNU C Library is free software; you can redistribute it and/or |
5 | modify it under the terms of the GNU Lesser General Public |
6 | License as published by the Free Software Foundation; either |
7 | version 2.1 of the License, or (at your option) any later version. |
8 | |
9 | The GNU C Library is distributed in the hope that it will be useful, |
10 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
11 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
12 | Lesser General Public License for more details. |
13 | |
14 | You should have received a copy of the GNU Lesser General Public |
15 | License along with the GNU C Library; if not, see |
16 | <https://www.gnu.org/licenses/>. */ |
17 | |
18 | /* clone() is even more special than fork() as it mucks with stacks |
19 | and invokes a function in the right context after its all over. */ |
20 | |
21 | #include <asm/errno.h> |
22 | #include <tcb-offsets.h> |
23 | #include <sysdep.h> |
24 | |
25 | /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg, |
26 | pid_t *ptid, void *tls, pid_t *ctid); */ |
27 | |
28 | .register %g2,#scratch |
29 | .register %g3,#scratch |
30 | |
31 | .text |
32 | |
33 | ENTRY (__clone) |
34 | save %sp, -192, %sp |
35 | cfi_def_cfa_register(%fp) |
36 | cfi_window_save |
37 | cfi_register(%o7, %i7) |
38 | |
39 | /* sanity check arguments */ |
40 | brz,pn %i0, 99f /* fn non-NULL? */ |
41 | mov %i0, %g2 |
42 | brz,pn %i1, 99f /* child_stack non-NULL? */ |
43 | mov %i2, %o0 /* clone flags */ |
44 | |
45 | /* The child_stack is the top of the stack, allocate one |
46 | whole stack frame from that as this is what the kernel |
47 | expects. Also, subtract STACK_BIAS. */ |
48 | sub %i1, 192 + 0x7ff, %o1 |
49 | mov %i3, %g3 |
50 | |
51 | mov %i4,%o2 /* PTID */ |
52 | mov %i5,%o3 /* TLS */ |
53 | ldx [%fp+0x7ff+176],%o4 /* CTID */ |
54 | |
55 | /* Do the system call */ |
56 | set __NR_clone, %g1 |
57 | ta 0x6d |
58 | bcs,pn %xcc, 98f |
59 | nop |
60 | brnz,pn %o1, __thread_start |
61 | nop |
62 | jmpl %i7 + 8, %g0 |
63 | restore %o0, %g0, %o0 |
64 | 99: mov EINVAL, %o0 |
65 | 98: call HIDDEN_JUMPTARGET(__errno_location) |
66 | mov %o0, %i0 |
67 | st %i0, [%o0] |
68 | jmpl %i7 + 8, %g0 |
69 | restore %g0,-1,%o0 |
70 | END(__clone) |
71 | |
72 | .type __thread_start,@function |
73 | __thread_start: |
74 | mov %g0, %fp /* terminate backtrace */ |
75 | call %g2 |
76 | mov %g3,%o0 |
77 | set __NR_exit, %g1 |
78 | ta 0x6d |
79 | nop |
80 | |
81 | .size __thread_start, .-__thread_start |
82 | |
83 | libc_hidden_def (__clone) |
84 | weak_alias (__clone, clone) |
85 | |