1 | /* SPDX-License-Identifier: GPL-2.0 */ |
2 | #include <linux/linkage.h> |
3 | #include <asm/assembler.h> |
4 | #include "abort-macro.S" |
5 | /* |
6 | * Function: v5tj_early_abort |
7 | * |
8 | * Params : r2 = pt_regs |
9 | * : r4 = aborted context pc |
10 | * : r5 = aborted context psr |
11 | * |
12 | * Returns : r4 - r11, r13 preserved |
13 | * |
14 | * Purpose : obtain information about current aborted instruction. |
15 | * Note: we read user space. This means we might cause a data |
16 | * abort here if the I-TLB and D-TLB aren't seeing the same |
17 | * picture. Unfortunately, this does happen. We live with it. |
18 | */ |
19 | .align 5 |
20 | ENTRY(v5tj_early_abort) |
21 | mrc p15, 0, r1, c5, c0, 0 @ get FSR |
22 | mrc p15, 0, r0, c6, c0, 0 @ get FAR |
23 | bic r1, r1, #1 << 11 | 1 << 10 @ clear bits 11 and 10 of FSR |
24 | tst r5, #PSR_J_BIT @ Java? |
25 | bne do_DataAbort |
26 | do_thumb_abort fsr=r1, pc=r4, psr=r5, tmp=r3 |
27 | ldreq r3, [r4] @ read aborted ARM instruction |
28 | uaccess_disable ip @ disable userspace access |
29 | teq_ldrd tmp=ip, insn=r3 @ insn was LDRD? |
30 | beq do_DataAbort @ yes |
31 | tst r3, #1 << 20 @ L = 0 -> write |
32 | orreq r1, r1, #1 << 11 @ yes. |
33 | b do_DataAbort |
34 | |