1 | /* Startup code compliant to the ELF C-SKY ABIV2. |
2 | Copyright (C) 2018-2024 Free Software Foundation, Inc. |
3 | This file is part of the GNU C Library. |
4 | |
5 | The GNU C Library is free software; you can redistribute it and/or |
6 | modify it under the terms of the GNU Lesser General Public |
7 | License as published by the Free Software Foundation; either |
8 | version 2.1 of the License, or (at your option) any later version. |
9 | |
10 | In addition to the permissions in the GNU Lesser General Public |
11 | License, the Free Software Foundation gives you unlimited |
12 | permission to link the compiled version of this file with other |
13 | programs, and to distribute those programs without any restriction |
14 | coming from the use of this file. (The GNU Lesser General Public |
15 | License restrictions do apply in other respects; for example, they |
16 | cover modification of the file, and distribution when not linked |
17 | into another program.) |
18 | |
19 | Note that people who make modified versions of this file are not |
20 | obligated to grant this special exception for their modified |
21 | versions; it is their choice whether to do so. The GNU Lesser |
22 | General Public License gives permission to release a modified |
23 | version without this exception; this exception also makes it |
24 | possible to release a modified version which carries forward this |
25 | exception. |
26 | |
27 | The GNU C Library is distributed in the hope that it will be useful, |
28 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
29 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
30 | Lesser General Public License for more details. |
31 | |
32 | You should have received a copy of the GNU Lesser General Public |
33 | License along with the GNU C Library. If not, see |
34 | <https://www.gnu.org/licenses/>. */ |
35 | |
36 | /* We need to call: |
37 | __libc_start_main (int (*main) (int, char **, char **), int argc, |
38 | char **argv, void (*init) (void), void (*fini) (void), |
39 | void (*rtld_fini) (void), void *stack_end) |
40 | */ |
41 | |
42 | #include <sysdep.h> |
43 | |
44 | .text |
45 | .globl _start; |
46 | .type _start,@function; |
47 | .align 4; |
48 | _start: |
49 | cfi_startproc |
50 | .cfi_label .Ldummy |
51 | cfi_undefined (lr) |
52 | subi sp, 8 |
53 | /* Clear the link register since this is the outermost frame. */ |
54 | movi lr, 0 |
55 | /* Pop argc off the stack and save a pointer to argv. */ |
56 | ldw a1, (sp, 8) /* Init argc for __libc_start_main. */ |
57 | addi a2, sp, 12 /* Init argv for __libc_start_main. */ |
58 | |
59 | /* Push stack limit. */ |
60 | stw a2, (sp, 8) |
61 | /* Push rtld_fini. */ |
62 | stw a0, (sp, 4) |
63 | |
64 | #ifdef SHARED |
65 | grs t0, .Lgetpc |
66 | .Lgetpc: |
67 | lrw gb, .Lgetpc@GOTPC |
68 | addu gb, t0 |
69 | |
70 | movi a3, 0 /* Used to be init. */ |
71 | stw a3, (sp, 0) /* Used to be fini. */ |
72 | |
73 | lrw t0, main@GOT |
74 | addu t0, gb |
75 | ldw a0, (t0, 0) |
76 | lrw t1, __libc_start_main@PLT |
77 | ldr.w t1, (gb, t1 << 0) |
78 | jsr t1 |
79 | |
80 | lrw t1, abort@PLT |
81 | ldr.w t1, (gb, t1 << 0) |
82 | jsr t1 |
83 | #else |
84 | movi a3, 0 /* Used to be init. */ |
85 | stw a3, (sp, 0) /* Used to be fini. */ |
86 | lrw a0, main |
87 | /* Let the libc call main and exit with its return code. */ |
88 | jsri __libc_start_main |
89 | |
90 | /* Should never get here. */ |
91 | jsri abort |
92 | #endif /* !SHARED */ |
93 | cfi_endproc |
94 | .size _start,.-_start |
95 | |
96 | |
97 | /* Define a symbol for the first piece of initialized data. */ |
98 | .data |
99 | .globl __data_start |
100 | __data_start: |
101 | .long 0 |
102 | .weak data_start |
103 | data_start = __data_start |
104 | |