| 1 | /* Copy memory block and return pointer to beginning of destination block |
|---|
| 2 | For Intel 80x86, x>=6. |
|---|
| 3 | This file is part of the GNU C Library. |
|---|
| 4 | Copyright (C) 1999-2024 Free Software Foundation, Inc. |
|---|
| 5 | |
|---|
| 6 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 7 | modify it under the terms of the GNU Lesser General Public |
|---|
| 8 | License as published by the Free Software Foundation; either |
|---|
| 9 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 10 | |
|---|
| 11 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 12 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 13 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 14 | Lesser General Public License for more details. |
|---|
| 15 | |
|---|
| 16 | You should have received a copy of the GNU Lesser General Public |
|---|
| 17 | License along with the GNU C Library; if not, see |
|---|
| 18 | <https://www.gnu.org/licenses/>. */ |
|---|
| 19 | |
|---|
| 20 | #include <sysdep.h> |
|---|
| 21 | #include "asm-syntax.h" |
|---|
| 22 | |
|---|
| 23 | #define PARMS 4 /* no space for saved regs */ |
|---|
| 24 | #define RTN PARMS |
|---|
| 25 | #define DEST RTN |
|---|
| 26 | #define SRC DEST+4 |
|---|
| 27 | #define LEN SRC+4 |
|---|
| 28 | |
|---|
| 29 | .text |
|---|
| 30 | #if defined SHARED && IS_IN (libc) |
|---|
| 31 | ENTRY_CHK (__memcpy_chk) |
|---|
| 32 | movl 12(%esp), %eax |
|---|
| 33 | cmpl %eax, 16(%esp) |
|---|
| 34 | jb HIDDEN_JUMPTARGET (__chk_fail) |
|---|
| 35 | END_CHK (__memcpy_chk) |
|---|
| 36 | libc_hidden_builtin_def (__memcpy_chk) |
|---|
| 37 | #endif |
|---|
| 38 | ENTRY (memcpy) |
|---|
| 39 | |
|---|
| 40 | movl %edi, %eax |
|---|
| 41 | movl DEST(%esp), %edi |
|---|
| 42 | movl %esi, %edx |
|---|
| 43 | movl SRC(%esp), %esi |
|---|
| 44 | |
|---|
| 45 | movl %edi, %ecx |
|---|
| 46 | xorl %esi, %ecx |
|---|
| 47 | andl $3, %ecx |
|---|
| 48 | movl LEN(%esp), %ecx |
|---|
| 49 | cld |
|---|
| 50 | jne .Lunaligned |
|---|
| 51 | |
|---|
| 52 | cmpl $3, %ecx |
|---|
| 53 | jbe .Lunaligned |
|---|
| 54 | |
|---|
| 55 | testl $3, %esi |
|---|
| 56 | je 1f |
|---|
| 57 | movsb |
|---|
| 58 | decl %ecx |
|---|
| 59 | testl $3, %esi |
|---|
| 60 | je 1f |
|---|
| 61 | movsb |
|---|
| 62 | decl %ecx |
|---|
| 63 | testl $3, %esi |
|---|
| 64 | je 1f |
|---|
| 65 | movsb |
|---|
| 66 | decl %ecx |
|---|
| 67 | 1: pushl %eax |
|---|
| 68 | movl %ecx, %eax |
|---|
| 69 | shrl $2, %ecx |
|---|
| 70 | andl $3, %eax |
|---|
| 71 | rep |
|---|
| 72 | movsl |
|---|
| 73 | movl %eax, %ecx |
|---|
| 74 | rep |
|---|
| 75 | movsb |
|---|
| 76 | popl %eax |
|---|
| 77 | |
|---|
| 78 | .Lend: movl %eax, %edi |
|---|
| 79 | movl %edx, %esi |
|---|
| 80 | movl DEST(%esp), %eax |
|---|
| 81 | |
|---|
| 82 | ret |
|---|
| 83 | |
|---|
| 84 | /* When we come here the pointers do not have the same |
|---|
| 85 | alignment or the length is too short. No need to optimize for |
|---|
| 86 | aligned memory accesses. */ |
|---|
| 87 | .Lunaligned: |
|---|
| 88 | shrl $1, %ecx |
|---|
| 89 | jnc 1f |
|---|
| 90 | movsb |
|---|
| 91 | 1: shrl $1, %ecx |
|---|
| 92 | jnc 2f |
|---|
| 93 | movsw |
|---|
| 94 | 2: rep |
|---|
| 95 | movsl |
|---|
| 96 | jmp .Lend |
|---|
| 97 | END (memcpy) |
|---|
| 98 | libc_hidden_builtin_def (memcpy) |
|---|
| 99 | |
|---|
