1 | /* __mpn_sub_n -- Add two limb vectors of the same length > 0 and store |
2 | sum in a third limb vector. |
3 | Copyright (C) 2000-2024 Free Software Foundation, Inc. |
4 | This file is part of the GNU MP Library. |
5 | |
6 | The GNU MP Library is free software; you can redistribute it and/or modify |
7 | it under the terms of the GNU Lesser General Public License as published by |
8 | the Free Software Foundation; either version 2.1 of the License, or (at your |
9 | option) any later version. |
10 | |
11 | The GNU MP Library is distributed in the hope that it will be useful, but |
12 | WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
13 | or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
14 | License for more details. |
15 | |
16 | You should have received a copy of the GNU Lesser General Public License |
17 | along with the GNU MP Library; see the file COPYING.LIB. If not, |
18 | see <https://www.gnu.org/licenses/>. */ |
19 | |
20 | /* |
21 | INPUT PARAMETERS |
22 | res_ptr %r2 |
23 | s1_ptr %r3 |
24 | s2_ptr %r4 |
25 | size %r5 |
26 | */ |
27 | |
28 | #include "sysdep.h" |
29 | #include "asm-syntax.h" |
30 | |
31 | ENTRY(__mpn_sub_n) |
32 | st %r6,24(%r15) # save register 6 |
33 | cfi_offset (%r6, -72) |
34 | sr %r1,%r1 |
35 | lhi %r0,1 # cannot use ahi to add carry, use slr |
36 | .L0: l %r6,0(%r1,%r3) # .L0 -> no carry from last sub |
37 | sl %r6,0(%r1,%r4) |
38 | st %r6,0(%r1,%r2) |
39 | la %r1,4(0,%r1) |
40 | brc 4,.L3 |
41 | .L1: brct %r5,.L0 |
42 | slr %r2,%r2 # no last carry to return |
43 | j .Lexit |
44 | .L2: l %r6,0(%r1,%r3) # .L2 -> carry from last sub |
45 | sl %r6,0(%r1,%r4) |
46 | brc 4,.L4 |
47 | slr %r6,%r0 # no carry yet, add carry from last sub |
48 | st %r6,0(%r1,%r2) |
49 | la %r1,4(0,%r1) |
50 | brc 11,.L1 # new carry ? |
51 | .L3: brct %r5,.L2 |
52 | lr %r2,%r0 # return last carry |
53 | j .Lexit |
54 | .L4: slr %r6,%r0 # already a carry, add carry from last sub |
55 | st %r6,0(%r1,%r2) |
56 | la %r1,4(0,%r1) |
57 | brct %r5,.L2 |
58 | lr %r2,%r0 # return last carry |
59 | .Lexit: l %r6,24(%r15) # restore register 6 |
60 | br %r14 |
61 | END(__mpn_sub_n) |
62 | |