1 | /* Add two limb vectors of the same length > 0 and store sum in a third |
2 | limb vector. |
3 | Copyright (C) 2001-2024 Free Software Foundation, Inc. |
4 | This file is part of the GNU MP Library. |
5 | |
6 | The GNU MP Library is free software; you can redistribute it and/or modify |
7 | it under the terms of the GNU Lesser General Public License as published by |
8 | the Free Software Foundation; either version 2.1 of the License, or (at your |
9 | option) any later version. |
10 | |
11 | The GNU MP Library is distributed in the hope that it will be useful, but |
12 | WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
13 | or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
14 | License for more details. |
15 | |
16 | You should have received a copy of the GNU Lesser General Public License |
17 | along with the GNU MP Library; see the file COPYING.LIB. If not, |
18 | see <https://www.gnu.org/licenses/>. */ |
19 | |
20 | /* |
21 | INPUT PARAMETERS |
22 | res_ptr %r2 |
23 | s1_ptr %r3 |
24 | s2_ptr %r4 |
25 | size %r5 |
26 | */ |
27 | |
28 | #include "sysdep.h" |
29 | #include "asm-syntax.h" |
30 | |
31 | .text |
32 | ENTRY(__mpn_add_n) |
33 | stg %r6,48(%r15) # save register 6 |
34 | cfi_offset (%r6,-112) |
35 | slgr %r1,%r1 |
36 | lghi %r0,1 # cannot use ahi to add carry, use alr |
37 | .L0: lg %r6,0(%r1,%r3) # .L0 -> no carry from last add |
38 | alg %r6,0(%r1,%r4) |
39 | stg %r6,0(%r1,%r2) |
40 | la %r1,8(%r1) |
41 | brc 3,.L3 |
42 | .L1: brct %r5,.L0 |
43 | slgr %r2,%r2 # no last carry to return |
44 | j .Lexit |
45 | .L2: lg %r6,0(%r1,%r3) # .L2 -> carry from last add |
46 | alg %r6,0(%r1,%r4) |
47 | brc 3,.L4 |
48 | algr %r6,%r0 # no carry yet, add carry from last add |
49 | stg %r6,0(%r1,%r2) |
50 | la %r1,8(%r1) |
51 | brc 12,.L1 # new carry ? |
52 | .L3: brct %r5,.L2 |
53 | lgr %r2,%r0 # return last carry |
54 | j .Lexit |
55 | .L4: algr %r6,%r0 # already a carry, add carry from last add |
56 | stg %r6,0(%r1,%r2) |
57 | la %r1,8(%r1) |
58 | brct %r5,.L2 |
59 | lgr %r2,%r0 # return last carry |
60 | .Lexit: lg %r6,48(%r15) # restore register 6 |
61 | br %r14 |
62 | END(__mpn_add_n) |
63 | |