1 | ! SPARC v8 __mpn_submul_1 -- Multiply a limb vector with a limb and |
2 | ! subtract the result from a second limb vector. |
3 | |
4 | ! Copyright (C) 1992-2024 Free Software Foundation, Inc. |
5 | |
6 | ! This file is part of the GNU MP Library. |
7 | |
8 | ! The GNU MP Library is free software; you can redistribute it and/or modify |
9 | ! it under the terms of the GNU Lesser General Public License as published by |
10 | ! the Free Software Foundation; either version 2.1 of the License, or (at your |
11 | ! option) any later version. |
12 | |
13 | ! The GNU MP Library is distributed in the hope that it will be useful, but |
14 | ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
15 | ! or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
16 | ! License for more details. |
17 | |
18 | ! You should have received a copy of the GNU Lesser General Public License |
19 | ! along with the GNU MP Library; see the file COPYING.LIB. If not, |
20 | ! see <https://www.gnu.org/licenses/>. |
21 | |
22 | |
23 | ! INPUT PARAMETERS |
24 | ! res_ptr o0 |
25 | ! s1_ptr o1 |
26 | ! size o2 |
27 | ! s2_limb o3 |
28 | |
29 | #include <sysdep.h> |
30 | |
31 | ENTRY(__mpn_submul_1) |
32 | sub %g0,%o2,%o2 ! negate ... |
33 | sll %o2,2,%o2 ! ... and scale size |
34 | sub %o1,%o2,%o1 ! o1 is offset s1_ptr |
35 | sub %o0,%o2,%g1 ! g1 is offset res_ptr |
36 | |
37 | mov 0,%o0 ! clear cy_limb |
38 | |
39 | LOC(loop): |
40 | ld [%o1+%o2],%o4 |
41 | ld [%g1+%o2],%g2 |
42 | umul %o4,%o3,%o5 |
43 | rd %y,%g3 |
44 | addcc %o5,%o0,%o5 |
45 | addx %g3,0,%o0 |
46 | subcc %g2,%o5,%g2 |
47 | addx %o0,0,%o0 |
48 | st %g2,[%g1+%o2] |
49 | |
50 | addcc %o2,4,%o2 |
51 | bne LOC(loop) |
52 | nop |
53 | |
54 | retl |
55 | nop |
56 | |
57 | END(__mpn_submul_1) |
58 | |