| 1 | /* Save current context and install the given one. |
|---|
| 2 | Copyright (C) 2012-2024 Free Software Foundation, Inc. |
|---|
| 3 | This file is part of the GNU C Library. |
|---|
| 4 | |
|---|
| 5 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 6 | modify it under the terms of the GNU Lesser General Public |
|---|
| 7 | License as published by the Free Software Foundation; either |
|---|
| 8 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 9 | |
|---|
| 10 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 11 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 12 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 13 | Lesser General Public License for more details. |
|---|
| 14 | |
|---|
| 15 | You should have received a copy of the GNU Lesser General Public |
|---|
| 16 | License along with the GNU C Library; if not, see |
|---|
| 17 | <https://www.gnu.org/licenses/>. */ |
|---|
| 18 | |
|---|
| 19 | #include <sysdep.h> |
|---|
| 20 | |
|---|
| 21 | #include "ucontext_i.h" |
|---|
| 22 | |
|---|
| 23 | |
|---|
| 24 | ENTRY(__swapcontext) |
|---|
| 25 | /* Load address of the context data structure we save in. */ |
|---|
| 26 | move.l 4(%sp), %a0 |
|---|
| 27 | |
|---|
| 28 | /* Save the preserved registers and the return address. */ |
|---|
| 29 | movem.l %d2-%d7, oGREGS+2*4(%a0) |
|---|
| 30 | movem.l %a2-%a6, oGREGS+10*4(%a0) |
|---|
| 31 | lea 4(%sp), %a1 |
|---|
| 32 | move.l %a1, oSP(%a0) |
|---|
| 33 | move.l (%sp), oPC(%a0) |
|---|
| 34 | fmovem.l %fpsr/%fpcr/%fpiar, oFPREGS(%a0) |
|---|
| 35 | fmovem.x %fp2-%fp7, oFP2(%a0) |
|---|
| 36 | cfi_def_cfa (%a0, 0) |
|---|
| 37 | cfi_offset (%d2, oGREGS+2*4) |
|---|
| 38 | cfi_offset (%d3, oGREGS+3*4) |
|---|
| 39 | cfi_offset (%a2, oGREGS+10*4) |
|---|
| 40 | cfi_offset (%pc, oPC) |
|---|
| 41 | |
|---|
| 42 | /* Load address of the context data structure we have to load. */ |
|---|
| 43 | move.l 8(%sp), %a1 |
|---|
| 44 | |
|---|
| 45 | /* Save the current signal mask and install the new one. */ |
|---|
| 46 | lea oSIGMASK(%a0), %a2 |
|---|
| 47 | move.l %a2, %d3 |
|---|
| 48 | lea oSIGMASK(%a1), %a2 |
|---|
| 49 | move.l %a2, %d2 |
|---|
| 50 | move.l #SIG_SETMASK, %d1 |
|---|
| 51 | move.l #__NR_sigprocmask, %d0 |
|---|
| 52 | trap #0 |
|---|
| 53 | cmp.l #-4095, %d0 /* Check %d0 for error. */ |
|---|
| 54 | jcs 0f |
|---|
| 55 | /* Restore registers. */ |
|---|
| 56 | move.l oGREGS+2*4(%a0), %d2 |
|---|
| 57 | cfi_restore (%d2) |
|---|
| 58 | move.l oGREGS+3*4(%a0), %d3 |
|---|
| 59 | cfi_restore (%d3) |
|---|
| 60 | move.l oGREGS+10*4(%a0), %a2 |
|---|
| 61 | cfi_restore (%a2) |
|---|
| 62 | jra SYSCALL_ERROR_LABEL /* Jump to error handler. */ |
|---|
| 63 | |
|---|
| 64 | 0: /* Load the new stack pointer. */ |
|---|
| 65 | move.l oSP(%a1), %sp |
|---|
| 66 | cfi_def_cfa (%a1, 0) |
|---|
| 67 | cfi_offset (%d2, oGREGS+2*4) |
|---|
| 68 | cfi_offset (%d3, oGREGS+3*4) |
|---|
| 69 | cfi_offset (%d4, oGREGS+4*4) |
|---|
| 70 | cfi_offset (%d5, oGREGS+5*4) |
|---|
| 71 | cfi_offset (%d6, oGREGS+6*4) |
|---|
| 72 | cfi_offset (%d7, oGREGS+7*4) |
|---|
| 73 | cfi_offset (%a2, oGREGS+10*4) |
|---|
| 74 | cfi_offset (%a3, oGREGS+11*4) |
|---|
| 75 | cfi_offset (%a4, oGREGS+12*4) |
|---|
| 76 | cfi_offset (%a5, oGREGS+13*4) |
|---|
| 77 | cfi_offset (%a6, oGREGS+14*4) |
|---|
| 78 | cfi_offset (%fp2, oFP2+0*12) |
|---|
| 79 | cfi_offset (%fp3, oFP2+1*12) |
|---|
| 80 | cfi_offset (%fp4, oFP2+2*12) |
|---|
| 81 | cfi_offset (%fp5, oFP2+3*12) |
|---|
| 82 | cfi_offset (%fp6, oFP2+4*12) |
|---|
| 83 | cfi_offset (%fp7, oFP2+5*12) |
|---|
| 84 | cfi_offset (%pc, oPC) |
|---|
| 85 | |
|---|
| 86 | /* Load the values of all the preserved registers (except SP). */ |
|---|
| 87 | movem.l oGREGS+2*4(%a1), %d2-%d7 |
|---|
| 88 | movem.l oGREGS+10*4(%a1), %a2-%a6 |
|---|
| 89 | fmovem.l oFPREGS(%a1), %fpsr/%fpcr/%fpiar |
|---|
| 90 | fmovem.x oFP2(%a1), %fp2-%fp7 |
|---|
| 91 | |
|---|
| 92 | /* Clear D0 to indicate success. */ |
|---|
| 93 | clr.l %d0 |
|---|
| 94 | |
|---|
| 95 | /* Fetch the address to return to. */ |
|---|
| 96 | move.l oPC(%a1), %a0 |
|---|
| 97 | |
|---|
| 98 | /* End FDE here, we fall into another context. */ |
|---|
| 99 | cfi_endproc |
|---|
| 100 | cfi_startproc |
|---|
| 101 | cfi_register (%pc, %a0) |
|---|
| 102 | |
|---|
| 103 | jmp (%a0) |
|---|
| 104 | |
|---|
| 105 | cfi_offset (%pc, -4) |
|---|
| 106 | PSEUDO_END(__swapcontext) |
|---|
| 107 | |
|---|
| 108 | weak_alias (__swapcontext, swapcontext) |
|---|
| 109 | |
|---|
