| 1 | /* Copyright (C) 2002-2024 Free Software Foundation, Inc. |
|---|
| 2 | This file is part of the GNU C Library. |
|---|
| 3 | |
|---|
| 4 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 5 | modify it under the terms of the GNU Lesser General Public |
|---|
| 6 | License as published by the Free Software Foundation; either |
|---|
| 7 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 8 | |
|---|
| 9 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 10 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 11 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 12 | Lesser General Public License for more details. |
|---|
| 13 | |
|---|
| 14 | You should have received a copy of the GNU Lesser General Public |
|---|
| 15 | License along with the GNU C Library; if not, see |
|---|
| 16 | <https://www.gnu.org/licenses/>. */ |
|---|
| 17 | |
|---|
| 18 | #include <sysdep.h> |
|---|
| 19 | #include <features.h> |
|---|
| 20 | |
|---|
| 21 | #include "ucontext_i.h" |
|---|
| 22 | |
|---|
| 23 | /* __swapcontext (ucontext_t *oucp, const ucontext_t *ucp) |
|---|
| 24 | |
|---|
| 25 | Saves the machine context in oucp such that when it is activated, |
|---|
| 26 | it appears as if __swapcontext() returned again, restores the |
|---|
| 27 | machine context in ucp and thereby resumes execution in that |
|---|
| 28 | context. |
|---|
| 29 | |
|---|
| 30 | This implementation is intended to be used for *synchronous* context |
|---|
| 31 | switches only. Therefore, it does not have to save anything |
|---|
| 32 | other than the PRESERVED state. */ |
|---|
| 33 | |
|---|
| 34 | ENTRY(__swapcontext) |
|---|
| 35 | /* While not part of the ABI a system call never clobbers r0 |
|---|
| 36 | or r1. So keeping the values here while calling |
|---|
| 37 | rt_sigprocmask is ok. */ |
|---|
| 38 | lgr %r1,%r2 |
|---|
| 39 | lgr %r0,%r3 |
|---|
| 40 | |
|---|
| 41 | /* Store fpu context. */ |
|---|
| 42 | stfpc SC_FPC(%r1) |
|---|
| 43 | std %f0,SC_FPRS(%r1) |
|---|
| 44 | std %f1,SC_FPRS+8(%r1) |
|---|
| 45 | std %f2,SC_FPRS+16(%r1) |
|---|
| 46 | std %f3,SC_FPRS+24(%r1) |
|---|
| 47 | std %f4,SC_FPRS+32(%r1) |
|---|
| 48 | std %f5,SC_FPRS+40(%r1) |
|---|
| 49 | std %f6,SC_FPRS+48(%r1) |
|---|
| 50 | std %f7,SC_FPRS+56(%r1) |
|---|
| 51 | std %f8,SC_FPRS+64(%r1) |
|---|
| 52 | std %f9,SC_FPRS+72(%r1) |
|---|
| 53 | std %f10,SC_FPRS+80(%r1) |
|---|
| 54 | std %f11,SC_FPRS+88(%r1) |
|---|
| 55 | std %f12,SC_FPRS+96(%r1) |
|---|
| 56 | std %f13,SC_FPRS+104(%r1) |
|---|
| 57 | std %f14,SC_FPRS+112(%r1) |
|---|
| 58 | std %f15,SC_FPRS+120(%r1) |
|---|
| 59 | |
|---|
| 60 | /* Set __swapcontext return value to 0. */ |
|---|
| 61 | slgr %r2,%r2 |
|---|
| 62 | |
|---|
| 63 | /* Store access registers. */ |
|---|
| 64 | stam %a0,%a15,SC_ACRS(%r1) |
|---|
| 65 | |
|---|
| 66 | /* Store general purpose registers. */ |
|---|
| 67 | stmg %r0,%r15,SC_GPRS(%r1) |
|---|
| 68 | |
|---|
| 69 | /* Store psw mask to 0x0 and addr to return address. Then the address |
|---|
| 70 | can be retrieved from the ucontext structure in the same way as if it |
|---|
| 71 | is created by kernel and passed to a signal-handler. */ |
|---|
| 72 | stg %r2,SC_PSW+0(%r1) |
|---|
| 73 | stg %r14,SC_PSW+8(%r1) |
|---|
| 74 | |
|---|
| 75 | /* rt_sigprocmask (SIG_SETMASK, &ucp->uc_sigmask, &oucp->uc_sigmask, |
|---|
| 76 | sigsetsize). */ |
|---|
| 77 | la %r2,SIG_SETMASK |
|---|
| 78 | lgr %r5,%r0 |
|---|
| 79 | la %r3,SC_MASK(%r5) |
|---|
| 80 | la %r4,SC_MASK(%r1) |
|---|
| 81 | lghi %r5,_NSIG8 |
|---|
| 82 | lghi %r1,SYS_ify(rt_sigprocmask) |
|---|
| 83 | svc 0 |
|---|
| 84 | |
|---|
| 85 | /* Load fpu context. */ |
|---|
| 86 | lgr %r5,%r0 |
|---|
| 87 | lfpc SC_FPC(%r5) |
|---|
| 88 | ld %f0,SC_FPRS(%r5) |
|---|
| 89 | ld %f1,SC_FPRS+8(%r5) |
|---|
| 90 | ld %f2,SC_FPRS+16(%r5) |
|---|
| 91 | ld %f3,SC_FPRS+24(%r5) |
|---|
| 92 | ld %f4,SC_FPRS+32(%r5) |
|---|
| 93 | ld %f5,SC_FPRS+40(%r5) |
|---|
| 94 | ld %f6,SC_FPRS+48(%r5) |
|---|
| 95 | ld %f7,SC_FPRS+56(%r5) |
|---|
| 96 | ld %f8,SC_FPRS+64(%r5) |
|---|
| 97 | ld %f9,SC_FPRS+72(%r5) |
|---|
| 98 | ld %f10,SC_FPRS+80(%r5) |
|---|
| 99 | ld %f11,SC_FPRS+88(%r5) |
|---|
| 100 | ld %f12,SC_FPRS+96(%r5) |
|---|
| 101 | ld %f13,SC_FPRS+104(%r5) |
|---|
| 102 | ld %f14,SC_FPRS+112(%r5) |
|---|
| 103 | ld %f15,SC_FPRS+120(%r5) |
|---|
| 104 | |
|---|
| 105 | /* Don't touch %a0 and %a1, used for thread purposes. */ |
|---|
| 106 | lam %a2,%a15,SC_ACRS+8(%r5) |
|---|
| 107 | |
|---|
| 108 | /* Load general purpose registers. */ |
|---|
| 109 | lmg %r0,%r15,SC_GPRS(%r5) |
|---|
| 110 | |
|---|
| 111 | /* Return. */ |
|---|
| 112 | br %r14 |
|---|
| 113 | END(__swapcontext) |
|---|
| 114 | weak_alias (__swapcontext, swapcontext) |
|---|
| 115 | |
|---|
