1/* Function cos vectorized with AVX2.
2 Copyright (C) 2014-2024 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <sysdep.h>
20#include "svml_d_trig_data.h"
21
22 .section .text.avx2, "ax", @progbits
23ENTRY (_ZGVdN4v_cos_avx2)
24
25/* ALGORITHM DESCRIPTION:
26
27 ( low accuracy ( < 4ulp ) or enhanced performance
28 ( half of correct mantissa ) implementation )
29
30 Argument representation:
31 arg + Pi/2 = (N*Pi + R)
32
33 Result calculation:
34 cos(arg) = sin(arg+Pi/2) = sin(N*Pi + R) = (-1)^N * sin(R)
35 sin(R) is approximated by corresponding polynomial
36 */
37 pushq %rbp
38 cfi_adjust_cfa_offset (8)
39 cfi_rel_offset (%rbp, 0)
40 movq %rsp, %rbp
41 cfi_def_cfa_register (%rbp)
42 andq $-64, %rsp
43 subq $448, %rsp
44 movq __svml_d_trig_data@GOTPCREL(%rip), %rax
45 vmovapd %ymm0, %ymm1
46 vmovupd __dInvPI(%rax), %ymm4
47 vmovupd __dRShifter(%rax), %ymm5
48
49/*
50 ARGUMENT RANGE REDUCTION:
51 Add Pi/2 to argument: X' = X+Pi/2
52 */
53 vaddpd __dHalfPI(%rax), %ymm1, %ymm7
54
55/* Get absolute argument value: X' = |X'| */
56 vandpd __dAbsMask(%rax), %ymm7, %ymm2
57
58/* Y = X'*InvPi + RS : right shifter add */
59 vfmadd213pd %ymm5, %ymm4, %ymm7
60 vmovupd __dC7(%rax), %ymm4
61
62/* Check for large arguments path */
63 vcmpnle_uqpd __dRangeVal(%rax), %ymm2, %ymm3
64
65/* N = Y - RS : right shifter sub */
66 vsubpd %ymm5, %ymm7, %ymm6
67 vmovupd __dPI1_FMA(%rax), %ymm2
68
69/* SignRes = Y<<63 : shift LSB to MSB place for result sign */
70 vpsllq $63, %ymm7, %ymm7
71
72/* N = N - 0.5 */
73 vsubpd __dOneHalf(%rax), %ymm6, %ymm0
74 vmovmskpd %ymm3, %ecx
75
76/* R = X - N*Pi1 */
77 vmovapd %ymm1, %ymm3
78 vfnmadd231pd %ymm0, %ymm2, %ymm3
79
80/* R = R - N*Pi2 */
81 vfnmadd231pd __dPI2_FMA(%rax), %ymm0, %ymm3
82
83/* R = R - N*Pi3 */
84 vfnmadd132pd __dPI3_FMA(%rax), %ymm3, %ymm0
85
86/* POLYNOMIAL APPROXIMATION: R2 = R*R */
87 vmulpd %ymm0, %ymm0, %ymm5
88 vfmadd213pd __dC6(%rax), %ymm5, %ymm4
89 vfmadd213pd __dC5(%rax), %ymm5, %ymm4
90 vfmadd213pd __dC4(%rax), %ymm5, %ymm4
91
92/* Poly = C3+R2*(C4+R2*(C5+R2*(C6+R2*C7))) */
93 vfmadd213pd __dC3(%rax), %ymm5, %ymm4
94
95/* Poly = R+R*(R2*(C1+R2*(C2+R2*Poly))) */
96 vfmadd213pd __dC2(%rax), %ymm5, %ymm4
97 vfmadd213pd __dC1(%rax), %ymm5, %ymm4
98 vmulpd %ymm5, %ymm4, %ymm6
99 vfmadd213pd %ymm0, %ymm0, %ymm6
100
101/*
102 RECONSTRUCTION:
103 Final sign setting: Res = Poly^SignRes */
104 vxorpd %ymm7, %ymm6, %ymm0
105 testl %ecx, %ecx
106 jne .LBL_1_3
107
108.LBL_1_2:
109 cfi_remember_state
110 movq %rbp, %rsp
111 cfi_def_cfa_register (%rsp)
112 popq %rbp
113 cfi_adjust_cfa_offset (-8)
114 cfi_restore (%rbp)
115 ret
116
117.LBL_1_3:
118 cfi_restore_state
119 vmovupd %ymm1, 320(%rsp)
120 vmovupd %ymm0, 384(%rsp)
121 je .LBL_1_2
122
123 xorb %dl, %dl
124 xorl %eax, %eax
125 vmovups %ymm8, 224(%rsp)
126 vmovups %ymm9, 192(%rsp)
127 vmovups %ymm10, 160(%rsp)
128 vmovups %ymm11, 128(%rsp)
129 vmovups %ymm12, 96(%rsp)
130 vmovups %ymm13, 64(%rsp)
131 vmovups %ymm14, 32(%rsp)
132 vmovups %ymm15, (%rsp)
133 movq %rsi, 264(%rsp)
134 movq %rdi, 256(%rsp)
135 movq %r12, 296(%rsp)
136 cfi_offset_rel_rsp (12, 296)
137 movb %dl, %r12b
138 movq %r13, 288(%rsp)
139 cfi_offset_rel_rsp (13, 288)
140 movl %ecx, %r13d
141 movq %r14, 280(%rsp)
142 cfi_offset_rel_rsp (14, 280)
143 movl %eax, %r14d
144 movq %r15, 272(%rsp)
145 cfi_offset_rel_rsp (15, 272)
146 cfi_remember_state
147
148.LBL_1_6:
149 btl %r14d, %r13d
150 jc .LBL_1_12
151
152.LBL_1_7:
153 lea 1(%r14), %esi
154 btl %esi, %r13d
155 jc .LBL_1_10
156
157.LBL_1_8:
158 incb %r12b
159 addl $2, %r14d
160 cmpb $16, %r12b
161 jb .LBL_1_6
162
163 vmovups 224(%rsp), %ymm8
164 vmovups 192(%rsp), %ymm9
165 vmovups 160(%rsp), %ymm10
166 vmovups 128(%rsp), %ymm11
167 vmovups 96(%rsp), %ymm12
168 vmovups 64(%rsp), %ymm13
169 vmovups 32(%rsp), %ymm14
170 vmovups (%rsp), %ymm15
171 vmovupd 384(%rsp), %ymm0
172 movq 264(%rsp), %rsi
173 movq 256(%rsp), %rdi
174 movq 296(%rsp), %r12
175 cfi_restore (%r12)
176 movq 288(%rsp), %r13
177 cfi_restore (%r13)
178 movq 280(%rsp), %r14
179 cfi_restore (%r14)
180 movq 272(%rsp), %r15
181 cfi_restore (%r15)
182 jmp .LBL_1_2
183
184.LBL_1_10:
185 cfi_restore_state
186 movzbl %r12b, %r15d
187 shlq $4, %r15
188 vmovsd 328(%rsp,%r15), %xmm0
189 vzeroupper
190
191 call JUMPTARGET(cos)
192
193 vmovsd %xmm0, 392(%rsp,%r15)
194 jmp .LBL_1_8
195
196.LBL_1_12:
197 movzbl %r12b, %r15d
198 shlq $4, %r15
199 vmovsd 320(%rsp,%r15), %xmm0
200 vzeroupper
201
202 call JUMPTARGET(cos)
203
204 vmovsd %xmm0, 384(%rsp,%r15)
205 jmp .LBL_1_7
206
207END (_ZGVdN4v_cos_avx2)
208

source code of glibc/sysdeps/x86_64/fpu/multiarch/svml_d_cos4_core_avx2.S